Note - ホコホコ hoko-hoko

2009

08-13

Flash版 Processing なライブラリ Frocessing を使ってみる

かっこいいアートっぽい描画ができるプログラム環境Processingを、それっぽくFlashのAS3で使えるようにしたライブラリが、Frocessingです。
gihyo.jpの記事（特集：FrocessingではじめるActionScriptドローイング｜gihyo.jp … 技術評論社）のサンプルコードを改造しつつ、試しにいろいろ作ってみました。（ライブラリは ver 0.5.7 を使用してます）

サンプル1

白いくねくねした草がランダムに発生してのびていきます。画面クリックで描画をリセットします。

Flash Study 白い草

PLAIN TEXT

Actionscript:

package
{
import flash.geom.Point;
import frocessing.display.*;
/**
* Frocessingのサンプル1
* くねくね線とランダムな円
* マウスクリックでリセット
*/
public class FrocessingSample01 extends F5MovieClip2DBmp
{
//描画サイズ
private var m_stage_width:Number = 500;
private var m_stage_height:Number = 500;
//図形描画の座標
private var m_points/*Point*/:Array; //座標を入れる
private var m_point_current_index:int = 0; //何番目の座標まで描画するか
public function FrocessingSample01(){
super();
}
//初期化 Stage が呼び込まれたときに自動的に呼ばれる
public function setup():void {
//描画範囲指定
size( m_stage_width, m_stage_height );
//背景色指定（引数の数によって色の指定方法が変わる）
background(0, 1); // color, alpha
//座標セット
setPoints();
}
//図形描画の座標をセット
private function setPoints():void {
m_points = new Array();
var len:int = m_stage_width - random(m_stage_height / 2);
var point_num:int = len / 10;
var step:int = len / point_num + random(5, 1);
var start_x:Number = Math.random() * m_stage_width; //ｙ軸スタート位置はランダム
var yure:Number = random(6, 2); //くねくねサイズ
var pt:Point;
for (var i:int = 0; i <point_num ; i++) {
pt = new Point(start_x + random(yure, -yure), -step * i );
m_points.push(pt);
}
//始点と終点は同じ値を2つ入れる（始点と終点はコントロールポイントになってるっぽいので）
pt = m_points[0].clone();
m_points.unshift(pt);
pt = m_points[m_points.length - 1].clone();
m_points.push(pt);
}
//描画（フレーム毎に繰り返し）
public function draw():void {
//マウスが押された場合
if ( isMousePressed ) {
//背景を塗りなおす（描画のリセット）
background(0, 1);
}
//原点の移動
translate( 0, m_stage_height);
//-----くねくね線-----
//塗りをなしに
noFill();
//線色の指定（引数の数によって色の指定方法が変わる）
stroke(255, 255, 255, 0.5); //R, G, B, alpha
//線幅指定
strokeWeight(0.1);
var pt:Point;
//頂点を複数持つ図形の描画
beginShape();
for (var i:int = 0; i <m_point_current_index ; i++) {
pt = m_points[i];
curveVertex(pt.x, pt.y);
}
endShape();
//-----ランダムな円-----
//線をなしに
//noStroke();
strokeWeight(1);
//塗り設定
fill(255, 255, 255, 0.5);
if(m_point_current_index> 0){
pt = m_points[m_point_current_index - 1];
}
else {
pt = m_points[0];
}
//円の描画
var maru_size:Number = random(15, 1);
ellipse(pt.x + random(15, -15), pt.y + random(10, -10), maru_size, maru_size);
//描画する座標進める
m_point_current_index++;
//最後の座標まで行ったら座標再設定
if (m_point_current_index> m_points.length) {
m_point_current_index = 0;
setPoints();
}
}
}
}

サンプル2

画面クリック位置に種をおいて、カラフルなくねくねした草が伸びていきます。右上の□四角をクリックすると、描画をリセットします。

Flash Study 色の種草

PLAIN TEXT

Actionscript:

package
{
import flash.geom.Point;
import frocessing.display.*;
/**
* Frocessingのサンプル2
* くねくね線と直線の枝と枝先にランダムな円
* マウスクリック位置で生える
* 背景は透過にしてみた
*/
public class FrocessingSample02 extends F5MovieClip2DBmp
{
//描画サイズ
private var m_stage_width:Number = 500;
private var m_stage_height:Number = 500;
//図形描画の座標
private var m_points/*Point*/:Array; //座標を入れる
private var m_point_current_index:int = 0; //何番目の座標まで描画するか
//線と塗りの色
private var m_color:uint;
public function FrocessingSample02(){
super();
}
//初期化 Stage が呼び込まれたときに自動的に呼ばれる
public function setup():void {
//描画範囲指定
size( m_stage_width, m_stage_height );
//背景色指定（引数の数によって色の指定方法が変わる）
background(0, 0); // color, alpha
}
//図形描画の座標をセット
private function setPoints(base_x:Number, base_y:Number):void {
m_point_current_index = 0;
m_points = new Array();
var len:int = m_stage_width - random(m_stage_height / 1.5);
var point_num:int = len / 10;
var step:int = len / point_num + random(5, 1);
var yure:Number = random(5, 1); //くねくねサイズ
var pt:Point;
for (var i:int = 0; i <point_num ; i++) {
pt = new Point(random(yure, -yure) + base_x, -step * i + base_y);
m_points.push(pt);
}
//始点と終点は同じ値を2つ入れる（始点と終点はコントロールポイントになってるっぽいので）
pt = m_points[0].clone();
m_points.unshift(pt);
pt = m_points[m_points.length - 1].clone();
m_points.push(pt);
}
//ランダムな色を設定
private function setRandomColor():void {
var r:uint = random(200, 50);
var g:uint = random(200, 50);
var b:uint = random(200, 50);
m_color = this.color(r, g, b);
}
//描画（フレーム毎に繰り返し）
public function draw():void {
//マウスが押された場合
if ( isMousePressed ){
//色再設定
setRandomColor();
//座標再設定
setPoints(mouseX, mouseY - m_stage_height);
}
if (m_points != null) {
var i:int = 0; //汎用カウンタ
var maru_size:Number = 0; //円サイズ
//原点の移動
translate( 0, m_stage_height);
//-----くねくね線-----
//塗りをなしに
noFill();
//線色の指定（引数の数によって色の指定方法が変わる）
stroke(m_color, 0.5); //color, alpha
//線幅指定
strokeWeight(0.1);
var pt:Point;
//頂点を複数持つ図形の描画
beginShape();
for (i = 0; i <m_point_current_index ; i++) {
pt = m_points[i];
curveVertex(pt.x, pt.y);
}
endShape();
//枝
if(m_point_current_index> 0 && m_point_current_index <m_points.length - 1){
//枝の先の座標設定
if(m_point_current_index> 0){
pt = m_points[m_point_current_index - 1];
}
else {
pt = m_points[0];
}
var eda_inc_x:Number = random(30, 0);
if (random(1)> 0.5) {
eda_inc_x *= -1;
}
var eda_inc_y:Number = random( -10, -30);
var eda_x:Number = eda_inc_x + pt.x;
var eda_y:Number = eda_inc_y + pt.y;
//直線
line(pt.x, pt.y, eda_x, eda_y);
//枝の先のランダムな円いくつか
noStroke();
fill(m_color, 0.5);
for (i = 0; i <5;i++){
maru_size = random(10, 1);
ellipse(eda_x + random(10, -10), eda_y + random(10, -10), maru_size, maru_size);
}
}
//伸び始め位置に円を書く
if (m_point_current_index == 0) {
noStroke();
fill(m_color, 0.5);
maru_size = 0;
for (i = 1; i <5; i++){
maru_size += i * random(5, 2);
ellipse(m_points[1].x, m_points[1].y, maru_size, maru_size);
}
}
//描画する座標進める
m_point_current_index++;
//最後の座標まで行ったら、次の座標が設定されるまで描画止める
if (m_point_current_index> m_points.length) {
m_point_current_index = 0;
m_points = null;
}
}
}
//描画をリセットする
public function reset():void {
background(0, 0);
}
}
}

サンプル3

白い花がランダムに咲きます。咲いた後は、フィルターをかけてぼかしています。画面クリックで描画をリセットします。

Flash Study 白い花

PLAIN TEXT

Actionscript:

package
{
import flash.geom.Point;
import flash.filters.BlurFilter;
import frocessing.display.*;
/**
* Frocessingのサンプル3
* ランダムな白い線の花にBlurフィルターをかける
*/
public class FrocessingSample03 extends F5MovieClip2DBmp
{
//描画サイズ
private var m_stage_width:Number = 500;
private var m_stage_height:Number = 500;
//花描画開始位置
private var m_flower_base:Point;
//花サイズ
private var m_flower_size:Number;
//花サイズ増分値
private var m_flower_step:Number;
//花の現在サイズ
private var m_flower_current_size:Number;
//花弁の数
private var m_kaben_num:int;
public function FrocessingSample03(){
super();
}
//初期化 Stage が呼び込まれたときに自動的に呼ばれる
public function setup():void {
//描画範囲指定
size( m_stage_width, m_stage_height );
//背景色指定（引数の数によって色の指定方法が変わる）
background(0, 1); // color, alpha
setFlower();
}
//描画する花の設定
public function setFlower():void {
m_flower_base = new Point(random(m_stage_width), random(m_stage_height));
m_flower_size = random(200, 20);
m_flower_step = m_flower_size / 10;
m_flower_current_size = m_flower_step;
m_kaben_num = random(8, 3);
}
//描画（フレーム毎に繰り返し）
public function draw():void {
translate( 0, 0);
//塗りをなしに
noFill();
//線色の指定（引数の数によって色の指定方法が変わる）
stroke(0xDDDDDD, 0.5); //color, alpha
//花を描く
var kaben_num:int = m_kaben_num;
var kaben_angle:Number = radians(360 / kaben_num);
var kaben_len:int = m_flower_current_size / 2;
var base_x:Number = m_flower_base.x;
var base_y:Number = m_flower_base.y;
beginShape();
curveVertex(base_x, base_y);
for (var i:int = 0; i <kaben_num ; i++) {
var x1:Number = cos(kaben_angle * i - kaben_angle / 3) * kaben_len / 2 + base_x;
var y1:Number = sin(kaben_angle * i - kaben_angle / 3) * kaben_len / 2 + base_y;
var x2:Number = cos(kaben_angle * i) * kaben_len + base_x;
var y2:Number = sin(kaben_angle * i) * kaben_len + base_y;
var x3:Number = cos(kaben_angle * i + kaben_angle / 3) * kaben_len / 2 + base_x;
var y3:Number = sin(kaben_angle * i + kaben_angle / 3) * kaben_len / 2 + base_y;
curveVertex(base_x, base_y);
curveVertex(x1, y1);
curveVertex(x2, y2);
curveVertex(x3, y3);
curveVertex(base_x, base_y);
}
curveVertex(base_x, base_y);
endShape();
//花のサイズ大きくする
m_flower_current_size += m_flower_step;
if (m_flower_current_size> m_flower_size) {
setFlower();
//フィルタかける
bitmapData.applyFilter(bitmapData, bitmapData.rect, new Point(0, 0), new BlurFilter(2, 2));
}
}
//描画のリセット
public function reset():void {
background(0, 1);
}
}
}

サンプル4

白い花の上にカラフルな草が伸びていきます。サンプル3の上にサンプル2 を重ねてるだけです。右上の□四角をクリックすると、描画をリセットします。

Flash Study 白い花と色の種草

PLAIN TEXT

Actionscript:

var smp3:FrocessingSample03 = new FrocessingSample03;
this.addChild(smp3);
var smp2:FrocessingSample02 = new FrocessingSample02;
this.addChild(smp2);
var button:Sprite = new Sprite;
button.graphics.beginFill(0xFFFFFF, 1);
button.graphics.drawRect(5, 5, 20, 20);
button.graphics.endFill();
button.alpha = 0.5;
button.buttonMode = true;
button.addEventListener(MouseEvent.ROLL_OVER,
function(e:Event):void {
button.alpha = 1;
});
button.addEventListener(MouseEvent.ROLL_OUT,
function(e:Event):void {
button.alpha = 0.7;
});
button.addEventListener(MouseEvent.MOUSE_UP,
function(e:Event):void {
smp2.reset();
smp3.reset();
});
this.addChild(button);

使い方の流れ

※F5MovieClipBitmapクラスしか使ってないので、他のクラスを継承した場合の作り方はわかりません…。

F5MovieClipBitmapを継承したクラス作成。
コンストラクタで親のコンストラクタ呼び出す。（明示的に呼び出さないといけないみたいです）
setupメソッドを作って、その中に初期化処理を書く。
drawメソッドを作って、その中に繰り返しの処理を書く。

描画関連のメソッドがAS3と全然違うので、ちょっと戸惑いました。（Processing使ったことないもので）
AS3の描画方法（graphicsクラスのメソッド）は忘れて使った方が混乱しなくていいかなと思います。

ちょこっとコードを書くだけで、結構かっこよさげな描画ができちゃいます。
特に曲線の描画がすごく楽です。
他のクラスも使っていろいろやってみたいです。

Categories: Flash / ActionScript, Note
Tags: actionscript, as, Flash, frocessing, processing

2009

06-24

Windows上で動くSMTP・POP3サーバ（DNSの機能もあり）Radish

※バージョンは3.0.0-b038使用（2009年6月現在は、3.3.0-b040が最新のようです）

Radishは、Windows上で使えるSMTPアプリケーションです。SMTPだけでなく、POP3・DNSの機能もあります。
設定が簡単なので、メール送受信テスト用に使用してみました。
ローカル内でのメールの送受信ができるようになるまでの、設定と使用方法のメモです。

Radishのサイトのダウンロードから、バイナリ版を落としてきます。
■Radish ダウンロード

解凍したら、Radish.exeを実行
初回起動時に、adish.exeが置いてあるフォルダに、初期設定用のファイル群が作成されます。
タスクバーにRadishのアイコン（白カブくん）が表示されます。

サーバの設定

タスクバーのRadishのアイコンを右クリック→「Radishを開く」で、Radishのメインウインドウを開きます。

SMTP/POP3サーバの設定

「設定」メニューから、「SMTP/POP3サーバの設定」を開きます。

基本設定

サーバ名：localserver
ドメイン名：example.net
ローカル内だけなので、名前は適当に。
他はデフォルトのままで。

SMTPサーバ

バインドアドレスは127.0.0.1にする（ローカル内のみにする）
他はデフォルトのままで。

※バインドアドレスを入れると、アプリケーションが起動するようになるようです（POP3・DNSも）
　起動したくないアプリケーションのバインドアドレスの欄は空欄にします。

POP3サーバ

バインドアドレスはSMTPと同じく 127.0.0.1 を入れる

パスワードのポリシーは、デフォルトのままだと、大文字小文字数字記号を組み合わせて、8文字以上でないとパスワードを登録できないので、面倒ならチェックをはずしたりして変更。

ユーザの登録

設定メニューから、「ユーザ」を開く
POP3（メール受信）で使用するユーザを登録する。
ここでは、テストとしてtest1というユーザを作成。

メーラー側の設定

メーラは何でもいいので、Radishで作成したPOP3ユーザ用のアカウントの設定をします。

受信（POP3）の設定: メールアドレス：test1@localhost; POP3サーバ：localhost

送信（SMTP）の設定: SMTPサーバ：localhost

※メールのあて先アドレスは、ユーザー名@ドメイン名
○test1@example.net

メールの送受信をする

サーバの設定時と同じく、タスクバーのRadishのアイコンを右クリック→「Radishを開く」で、Radishのメインウインドウを開きます。

左下の「Log」タブを選択すると、メール送受信のログが表示されます。

「Log」タブの隣の「Mail」タブを選択すると、送信中のメールキューと、受信したメールボックスのリストが表示されます。

ここで、メールの送受信の状態を調べます。

※メールキューを消す
なぜかアプリケーション側から消せない...ので、メールキューのファイルを直接消します。
Radish.exeが置いてあるフォルダと同じところに、mqueue フォルダがあります。
mqueueフォルダの下に、キューのファイルがたまっているので、直接このファイルを消します。

サーバの停止と起動

タスクバーのRadishのアイコンを右クリック→「サーバ起動」「サーバ停止」「サーバ再起動」を選択します。
もしくは、Radishのメインウインドの、「ツール」メニューから、「サーバ起動」「サーバ停止」「サーバ再起動」を選択します。

Categories: Note, Web
Tags: pop3, smtp, windows

2009

05-27

物理エンジンライブラリ Box2DFlashAS3 衝突判定と衝突のグループ・カテゴリ分け

Box2Dの衝突判定と、衝突のグループ・カテゴリ分けをする方法のメモです。

衝突判定

Box2Dでは、衝突が起こった物体同士のリストが作成させるので、そのリストを取得して、衝突判定をします。
衝突の起こった物体同士は、b2Worldクラスのm_contactList（ContactListクラス）にb2Contactオブジェクトとして入れられます。
このm_contactListを、Box2Dの演算時に、順次取り出して、衝突時の処理をします。

衝突のグループ・カテゴリ分け

Box2Dで作った物体は、デフォルトでは全ての物体と衝突するようになっています。
これを、ある物体とは衝突するけどある物体とは衝突しないような、グループ分けをするには、b2ShapeDefクラスのfilter（b2FilterDataクラス）の値を変更します。

衝突のグループ・カテゴリ分けの方法

下記の二種類があって、両方を併用することもできます。

groupIndex を使用する
categoryBit と maskBit を使用する

1.groupIndexを使用する

groupIndexを0以外の値を指定して、グループを作る。値が正負かによって、処理が異なる。

正の同じ値のグループ内の物体は、maskBit・categoryBitの値が何であれ、必ず衝突する。
負の同じ値のグループ内の物体は、maskBit・categoryBitの値が何であれ、必ず衝突しない。

別の値のグループとは、maskBit・categoryBitの値によって、衝突判定が決まる。

2.categoryBit と maskBit を使用する

16進数4桁（2進数16桁）の categoryBit を指定。（0x0001）
maskBitも同じく16進数4桁をつける
categoryBitとmaskBitを論理積（AND)で演算して、0にならない物体同士は衝突。

	Aグループ：
		categoryBit=0x0001（0000 0000 0000 0001）
	Bグループ：
		categoryBit=0x0002（0000 0000 0000 0010）
	Cグループ：
		categoryBit=0x0004（0000 0000 0000 0100）

	各グループ内の物体同士を衝突させる
		A
		maskBit=0x0003（0000 0000 0000 0011）
		B
		maskBit=0x0003（0000 0000 0000 0011）
		C
		maskBit=0x0003（0000 0000 0000 0100）

	各グループ内の物体同士と、AとBグループの物体同士を衝突させる
		AとB
		maskBit=0x0006（0000 0000 0000 0011）
		C
		maskBit=0x0006（0000 0000 0000 0100）

maskBit・categoryBitのみで衝突のグループ分けしたい場合は、groupIndexをデフォルトの0のままにしておく

Body作成後に、m_filterの値を変えた場合は、b2WorldクラスのRefilterメソッドを使って、フィルターを再設定してやる必要があるようです。
変えなくてもフィルター設定反映されたのですが、念のため。

サンプルコード

実行結果（きのこと箱）

※Box2Dのまとめたクラス（Box2DBase）を作って、基本クラスで使ってます。ソースは物理エンジンライブラリ Box2DFlashAS3（基本）にあります。

マウスジョイントの辺りは、Box2Dの付属コード、TestBedのTest.asのサンプルからほぼコピペです。

PLAIN TEXT

Actionscript:

public class StudyB2Contact extends B2Base
{
public function StudyB2Contact()
{
makeB2Walls();
makeGroup();
this.addEventListener(Event.ENTER_FRAME, update, false, 0, true);
//マウスジョイント用
this.addEventListener(MouseEvent.MOUSE_DOWN, this.onMouseDown, false, 0, true);
this.addEventListener(MouseEvent.MOUSE_UP, this.onMouseUp, false, 0, true);
}
//Box2D 上下左右の壁作成
private function makeB2Walls():void {
//デフォルトの衝突フィルターの値
//categorybit = 0x0001
//maskBit = 0xFFFF
//groupIndex = 0
this.makeB2BodyBox(620, 10, 300, 5, 0, 0, 0.5, 0.5); //上
this.makeB2BodyBox(620, 10, 300, 495, 0, 0, 0.5, 0.5); //下
this.makeB2BodyBox(10, 520, 5, 250, 0, 0, 0.5, 0.5); //左
this.makeB2BodyBox(10, 520, 595, 250, 0, 0, 0.5, 0.5); //右
}
//衝突のグループ分けした物体作成
private function makeGroup():void {
//表示用Sprite
var disp_box = new Sprite();
this.addChild(disp_box);
var disp_item = new Sprite();
this.addChild(disp_item);
var i:int;
var s_item_num:int = 3;
var item_size:int = 40;
var box_size:int = 100;
var category_bit:uint;
var mask_bit:uint;
//赤と赤、緑と緑、赤と緑は衝突
//壁とも衝突
//赤色
category_bit = 0x0002; // 0000 0000 0000 0010
mask_bit = 0x0007; // 0000 0000 0000 0111
var box_red:Sprite = new box_red_mc as Sprite;
this.setBox(box_size, box_size, 120, 150, box_red, disp_box, category_bit, mask_bit);
for (i = 0; i <s_item_num; i++) {
var kinoko_red:Sprite = new kinoko_red_mc as Sprite;
this.setCircle(item_size, Math.random() * 500, 20, kinoko_red, disp_item, category_bit, mask_bit);
}
//緑色
category_bit = 0x0004; // 0000 0000 0000 0100
mask_bit = 0x0007; // 0000 0000 0000 0111
var box_green:Sprite = new box_green_mc as Sprite;
this.setBox(box_size, box_size, 240, 350, box_green, disp_box, category_bit, mask_bit);
for (i = 0; i <s_item_num; i++) {
var kinoko_green:Sprite = new kinoko_green_mc as Sprite;
this.setCircle(item_size, Math.random() * 500, 20, kinoko_green, disp_item, category_bit, mask_bit);
}
//黄と黄は衝突
//壁とも衝突
//黄色
category_bit = 0x0011; // 0000 0000 0001 0001
mask_bit = 0x0011; // 0000 0000 0001 0001
var box_yellow:Sprite = new box_yellow_mc as Sprite;
this.setBox(box_size, box_size, 480, 350, box_yellow, disp_box, category_bit, mask_bit);
for (i = 0; i <s_item_num; i++) {
var kinoko_yellow:Sprite = new kinoko_yellow_mc as Sprite;
this.setCircle(item_size, Math.random() * 500, 20, kinoko_yellow, disp_item, category_bit, mask_bit);
}
//青は壁以外衝突しない（青と青も衝突しない）
//青色
category_bit = 0x0008; // 0000 0000 0000 1000
mask_bit = 0x0001; // 0000 0000 0000 0001
var box_blue:Sprite = new box_blue_mc as Sprite;
this.setBox(box_size, box_size, 360, 150, box_blue, disp_box, category_bit, mask_bit);
for (i = 0; i <s_item_num; i++) {
var kinoko_blue:Sprite = new kinoko_blue_mc as Sprite;
this.setCircle(item_size, Math.random() * 500, 20, kinoko_blue, disp_item, category_bit, mask_bit);
}
}
//四角い物体作成
private function setBox(w:Number, h:Number, x:Number, y:Number, disp_block:Sprite, disp_blocks:Sprite, category_bits:uint, mask_bit:uint):void {
disp_block.width = w;
disp_block.height = h;
var block:b2Body = this.makeB2BodyBox(w, h, x, y, 0, 0, 0.5, 0.5, disp_block, disp_blocks);
block.m_shapeList.m_filter.categoryBits = category_bits;
block.m_shapeList.m_filter.maskBits = mask_bit;
//フィルターの更新
this.m_b2_world.Refilter(block.m_shapeList);
}
//丸い物体作成
private function setCircle(size:Number, x:Number, y:Number, disp_block:Sprite, disp_blocks:Sprite, category_bits:uint, mask_bit:uint):void {
disp_block.width = size;
disp_block.height = size;
var block:b2Body = this.makeB2BodyCircle(size, x, y, 1, 0.5, 0.5, disp_block, disp_blocks);
block.m_shapeList.m_filter.categoryBits = category_bits;
block.m_shapeList.m_filter.maskBits = mask_bit;
//フィルターの更新
this.m_b2_world.Refilter(block.m_shapeList);
}
//演算
private function update(e:Event):void {
m_b2_world.Step(m_b2_timeStep, m_b2_iterations);
for (var bb:b2Body = m_b2_world.m_bodyList; bb; bb = bb.m_next){
if (bb.m_userData is Sprite){
bb.m_userData.x = bb.GetPosition().x * m_b2_physcale;
bb.m_userData.y = bb.GetPosition().y * m_b2_physcale;
bb.m_userData.rotation = bb.GetAngle() * (180 / Math.PI);
}
}
//衝突判定
for (var cbb:b2Contact = m_b2_world.m_contactList; cbb; cbb = cbb.m_next) {
var userdata1:MovieClip = cbb.m_shape1.m_body.m_userData as MovieClip;
if (userdata1 is Sprite) {
userdata1.gotoAndPlay("contact");
}
var userdata2:MovieClip = cbb.m_shape2.m_body.m_userData as MovieClip;
if (userdata2 is Sprite) {
userdata2.gotoAndPlay("contact");
}
}
//マウスジョイント
this.updateMouseWorld();
this.mouseDrag();
}
//マウスジョイント設定 ---------------------------------------------------------------------
//Box2D付属のGeneralのInputをほぼこコピペ
// world mouse position
private var m_mouseJoint:b2MouseJoint; //マウスジョイント
private var m_mouseXWorldPhys:Number; //メートル単位のマウス座標
private var m_mouseYWorldPhys:Number;
private var m_mouse_dowm:Boolean = false; //マウスボタン押されてるか
private function onMouseDown(e:Event):void {
this.m_mouse_dowm = true;
}
private function onMouseUp(e:Event):void {
this.m_mouse_dowm = false;
}
//マウス座標取得
public function updateMouseWorld():void{
//メートル単位のマウス座標に変換
m_mouseXWorldPhys = this.mouseX / this.m_b2_physcale;
m_mouseYWorldPhys = this.mouseY / this.m_b2_physcale;
}
//マウスドラッグ時
public function mouseDrag():void{
//マウスボタン押した（ジョイントまだ）
if (this.m_mouse_dowm && !this.m_mouseJoint){
var body:b2Body = GetBodyAtMouse(); //マウスの下の物体取得
if (body)
{
var md:b2MouseJointDef = new b2MouseJointDef();
md.body1 = this.m_b2_world.GetGroundBody();
md.body2 = body;
md.target.Set(this.m_mouseXWorldPhys, this.m_mouseYWorldPhys);
md.maxForce = 300000.0 * body.GetMass();
md.timeStep = this.m_b2_timeStep;
m_mouseJoint = this.m_b2_world.CreateJoint(md) as b2MouseJoint;
body.WakeUp();
}
}
//マウスボタン離した
if (!this.m_mouse_dowm){
if (this.m_mouseJoint)
{
this.m_b2_world.DestroyJoint(m_mouseJoint);
m_mouseJoint = null;
}
}
//マウス押されてる状態（ジョイントされてる）
if (this.m_mouse_dowm && this.m_mouseJoint)
{
var p2:b2Vec2 = new b2Vec2(this.m_mouseXWorldPhys, this.m_mouseYWorldPhys);
m_mouseJoint.SetTarget(p2);
}
}
//マウスの下の物体取得
private var mousePVec:b2Vec2 = new b2Vec2();
public function GetBodyAtMouse(includeStatic:Boolean=false):b2Body{
// Make a small box.
mousePVec.Set(this.m_mouseXWorldPhys, this.m_mouseYWorldPhys);
var aabb:b2AABB = new b2AABB();
aabb.lowerBound.Set(this.m_mouseXWorldPhys - 0.001, this.m_mouseYWorldPhys - 0.001);
aabb.upperBound.Set(this.m_mouseXWorldPhys + 0.001, this.m_mouseYWorldPhys + 0.001);
// Query the world for overlapping shapes.
var k_maxCount:int = 10;
var shapes:Array = new Array();
var count:int = this.m_b2_world.Query(aabb, shapes, k_maxCount);
var body:b2Body = null;
for (var i:int = 0; i <count; ++i)
{
if (shapes[i].GetBody().IsStatic() == false || includeStatic)
{
var tShape:b2Shape = shapes[i] as b2Shape;
var inside:Boolean = tShape.TestPoint(tShape.GetBody().GetXForm(), mousePVec);
if (inside)
{
body = tShape.GetBody();
break;
}
}
}
return body;
}
}

Categories: Flash / ActionScript, Note
Tags: actionscript, as, box2d, collision, contact, Flash